主页 > 知识库 > 数据库 > SQL server >

利用SQL Server 2005数据库邮件发送电子邮件

来源: 作者: 发表于:2009-09-29 11:37  点击:
数据库邮件——SQL Server 2005中的一个新型电子邮件发送平台。在这篇文章的结尾,为了确保我们的数据库邮件设置正常工作,我发送了一封试验邮件。在本文中,我将基于该邮件来探讨在SQL Server 2005中发送数据库邮件的一些高级功能。

随着技术的不断进步,我们需要知道在你的信息系统发生了什么,为了满足这种日益增长的需求要求有更高级的方法。

能够迅速和简单地了解形势,尤其是了解潜在的问题,这对于我们非常重要。微软不断的生产新产品来传递这种能力,在SQL Server 2005中可获得的一些数据库特别选项有:查询通知、通知服务、服务代理和数据库邮件。

数据库邮件——SQL Server 2005中的一个新型电子邮件发送平台。在这篇文章的结尾,为了确保我们的数据库邮件设置正常工作,我发送了一封试验邮件。在本文中,我将基于该邮件来探讨在SQL Server 2005中发送数据库邮件的一些高级功能。

数据库邮件选项

SQL Server 2005数据库邮件为发送电子邮件信息提供了多种选项。这些选项包括:发送附件,设置敏感度和重要性,还包括查询结果,用HTML格式发送电子邮件信息。

要在SQL Server 2005中发送电子邮件,你需要列表A中的脚本来建立一个包含一些数据的表格,以便稍后能够使用查询结果选项。脚本建立一个表格并加载一些试验数据。

IF EXISTS(SELECT name from master..sysdatabases where name = 'SalesDB')
      DROP DATABASE SalesDB

CREATE DATABASE SalesDB;

USE SALESDB;
CREATE TABLE SalesHistory
(
      SaleID INT IDENTITY(1,1),
      Product VARCHAR(30),
      SaleDate SMALLDATETIME,
      SalePrice MONEY
)

DECLARE @i SMALLINT

SET @i = 1

WHILE (@i <=100)

BEGIN
      INSERT INTO SalesHistory
      (Product, SaleDate, SalePrice)
      VALUES
      ('Computer', DATEADD(mm, @i, '3/11/1919'), DATEPART(ms, GETDATE()) + (@i + 57) )


      INSERT INTO SalesHistory
      (Product, SaleDate, SalePrice)
      VALUES
      ('BigScreen', DATEADD(mm, @i, '3/11/1927'), DATEPART(ms, GETDATE()) + (@i + 13) )


      INSERT INTO SalesHistory
      (Product, SaleDate, SalePrice)
      VALUES
      ('PoolTable', DATEADD(mm, @i, '3/11/1908'), DATEPART(ms, GETDATE()) + (@i + 29) )


      SET @i = @i + 1

END

发送附件

通过电子邮件发送文件附件的能力对工作效率来说是十分重要的。下面的脚本将会发送一封电子邮件,其中包含文件名为FileAttachment.txt的附件,给附件存储于我的C盘驱动器上。

你需要确保文件的存在,这样发送过程就不会发生错误。

EXEC msdb.dbo.sp_send_dbmail
@recipients=N'chapman.tim@gmail.com',
@body='Message Body',
@subject ='Message Subject',
@profile_name ='Database-mailProfile',
@file_attachments ='C://FileAttachment.txt';

敏感度和重要性

通常需要将一封邮件标记为敏感或重要,以使得收件人知道这些信息需要小心保护。下面的脚本将会发送一封邮件,敏感度为私人,重要性为高级。此外,脚本将会复制邮件地址yourname@yourdomain.com到信件中。

EXEC msdb.dbo.sp_send_dbmail
@recipients=N'chapman.tim@gmail.com',
@body='Message Body',
@sensitivity ='Personal',
@importance ='High',
@copy_recipients ='chapman.tim@gmail.com',
@subject ='Message Subject',
@profile_name ='Database-mailProfile';

查询结果

拥有电子邮件发送能力的数据库引擎的一个重要特征是它可以让你向发送过程传递一个查询。在SQL Mail和Database Mail中都有该特性。Database Mail中的一个新特性是可以将查询结果作为附件,这一点在下面的脚本中展示。如果你不将查询结果作为一文件,那么它将被放置在邮件正文中。见列表B。

EXEC msdb.dbo.sp_send_dbmail

@recipients=N'chapman.tim@gmail.com',
@body='Message Body',

@subject ='Message Subject',
@profile_name ='DatabaseMailProfile',
@query ='SELECT Product FROM sb2..SalesHistory GROUP BY Product HAVING COUNT(*) > 3',

@attach_query_result_as_file = 1,
@query_attachment_filename ='Results.txt'

HTML格式的信件

在数据库邮件中我最喜爱的新特征是可以将你的邮件格式化为HTML格式。简单看来,这没什么大不了的,但是这确实带来一些很好的可能性。在前面的例子中,你发送的查询结果包含在邮件正文中,因为该例子只包含一列数据,所以看起来没有什么不方便的。

但是,当在查询结果集中包含多个域时,格式化变得每况愈下。一个好消息是,可以很简单的使用SQL Server 2005中的一些XML和HTML新特征来格式化你的查询结果集,因此,可以很容易的在信件中查看查询结果。列表C中的脚本演示了如何利用查询结果发送一封XML/HTML格式的电子邮件。

DECLARE @xml NVARCHAR(MAX)
DECLARE @body NVARCHAR(MAX)

SET @xml =CAST(( SELECT Product AS 'td','',SUM(SalePrice) AS 'td'
FROM SalesHistory GROUP BY Product FOR XML PATH('tr'), ELEMENTS ) AS NVARCHAR(MAX))

SET @body ='<html><H1>Sales Reports</H1><body bgcolor=yellow><table border = 2><tr><th>Product</th><th>SaleAmount</th></tr>'
SET @body = @body + @xml +'</table></body></html>'

EXEC msdb.dbo.sp_send_dbmail
@recipients =N'chapman.tim@gmail.com',
@body = @body,
@body_format ='HTML',
@subject ='Message Subject',
@profile_name ='DatabaseMailProfile'

当你发送HTML格式的邮件时,允许你将查询结果嵌入到邮件的查询部分,从而可以将查询结果格式化成为更容易看的形式。(虽然,你可能会争论说我在信件中使用的黄色背景,看起来并不是很舒服。)

可能性

当你能够从数据库引擎发送电子邮件时,这就引起了很多可能性。加上一些额外的逻辑和构建,你就可以编写一个国产邮件系统,这样就可以确保你总能找到想要找的人。在我的关于数据库邮件系列三中,我将介绍如何书写这样一个应用。

    有帮助
    (3)
    42.9%
    没帮助
    (4)
    57.1%